Contract Address Details

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import {ReentrancyGuardUpgradeable} from "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import {ECDSAUpgradeable} from "@openzeppelin/contracts-upgradeable/utils/cryptography/ECDSAUpgradeable.sol";
import {SafeMathUpgradeable} from "@openzeppelin/contracts-upgradeable/utils/math/SafeMathUpgradeable.sol";
import {AddressUpgradeable} from "@openzeppelin/contracts-upgradeable/utils/AddressUpgradeable.sol";

import {BlockContext} from "./base/BlockContext.sol";
import {Multicall} from "./base/Multicall.sol";

import {IAlphaKeysFactory} from "./interfaces/IAlphaKeysFactory.sol";
import {AlphaKeysFactoryStorage} from "./storage/AlphaKeysFactoryStorage.sol";
import {IAlphaKeysToken} from "./interfaces/IAlphaKeysToken.sol";
import {IAlphaKeysVault} from "./interfaces/IAlphaKeysVault.sol";

import {NumberMath} from "./libraries/NumberMath.sol";
import {ThreeThreeTypes} from "./libraries/ThreeThreeTypes.sol";
import {TokenTypes} from "./libraries/TokenTypes.sol";
import {LimitOrderTypes} from "./libraries/LimitOrderTypes.sol";

import {AlphaKeysTokenProxy} from "./AlphaKeysTokenProxy.sol";

import {TransferHelper} from "./libraries/TransferHelper.sol";

contract AlphaKeysFactory is
    IAlphaKeysFactory,
    BlockContext,
    Multicall,
    OwnableUpgradeable,
    ReentrancyGuardUpgradeable,
    AlphaKeysFactoryStorage
{
    using SafeMathUpgradeable for uint256;
    using NumberMath for uint256;
    using AddressUpgradeable for address;
    //
    modifier onlyAdmin() {
        require(_msgSender() == _admin, "AKF_NA");
        _;
    }

    modifier onlyToken(address token) {
        require(token != address(0), "AKF_TZ");
        require(
            (_keysPlayers[token] != address(0) || _keysTwitters[token] > 0),
            "AKF_BT"
        );
        _;
    }

    modifier onlyPlayer(address player) {
        require(player != address(0), "AKF_PZ");
        require((_playerKeys[player] != address(0)), "AKF_BP");
        _;
    }

    modifier notContract() {
        // caller is contract
        require(!_msgSender().isContract(), "AKF_CIC");
        _;
    }

    receive() external payable {}

    function initialize() external initializer {
        __Ownable_init();
        __ReentrancyGuard_init();
        //
        _protocolFeeDestination = _msgSender();
        _protocolFeeRatio = 50000;
        _playerFeeRatio = 50000;
        _admin = _msgSender();
    }

    function getAlphaKeysTokenImplementation()
        external
        view
        override
        returns (address)
    {
        return _playerShareTokenImplementation;
    }

    function setAlphaKeysTokenImplementation(
        address playerShareTokenImplementationArg
    ) external onlyOwner {
        _playerShareTokenImplementation = playerShareTokenImplementationArg;
    }

    function setAdmin(address admin) external onlyOwner {
        _admin = admin;
    }

    function getAdmin() external view returns (address) {
        return _admin;
    }

    function setBTC(address btc) external onlyOwner {
        require(btc.isContract(), "AKF_BINC");
        _btc = btc;
    }

    function getBTC() external view override returns (address) {
        return _btc;
    }

    function setVault(address vault) external onlyOwner {
        require(vault.isContract(), "AKF_VINC");
        _vault = vault;
    }

    function getVault() external view override returns (address) {
        return _vault;
    }

    function setBTCPrice(uint256 btcPrice) external onlyOwner {
        _btcPrice = btcPrice;
    }

    function getBTCPrice() external view returns (uint256) {
        return _btcPrice;
    }

    function getPlayerKeys(address player) external view returns (address) {
        return _playerKeys[player];
    }

    function getKeysPlayer(address token) external view returns (address) {
        return _keysPlayers[token];
    }

    function getTwitterKeys(uint256 twitterId) external view returns (address) {
        return _twitterKeys[twitterId];
    }

    function getKeysTwitters(address token) external view returns (uint256) {
        return _keysTwitters[token];
    }

    function setProtocolFeeRatio(uint24 protocolFeeRatio) external onlyOwner {
        _protocolFeeRatio = protocolFeeRatio;
    }

    function getProtocolFeeRatio() external view returns (uint24) {
        return _protocolFeeRatio;
    }

    function setPlayerFeeRatio(uint24 playerFeeRatio) external onlyOwner {
        _playerFeeRatio = playerFeeRatio;
    }

    function getPlayerFeeRatio() external view returns (uint24) {
        return _playerFeeRatio;
    }

    function getProtocolFeeDestination()
        external
        view
        override
        returns (address)
    {
        return _protocolFeeDestination;
    }

    function setProtocolFeeDestination(
        address protocolFeeDestination
    ) external onlyOwner {
        _protocolFeeDestination = protocolFeeDestination;
    }

    // for create token

    function getCreateForTwitterMessageHash(
        uint256 twitterId,
        string calldata name,
        string calldata symbol
    ) public view returns (bytes32) {
        uint256 chainId;
        assembly {
            chainId := chainid()
        }
        return
            keccak256(
                abi.encode(address(this), chainId, twitterId, name, symbol)
            );
    }

    function _verifyCreateTokenSigner(
        uint256 twitterId,
        string calldata name,
        string calldata symbol,
        bytes memory signature
    ) internal view returns (address, bytes32) {
        bytes32 messageHash = getCreateForTwitterMessageHash(
            twitterId,
            name,
            symbol
        );
        address signer = ECDSAUpgradeable.recover(
            ECDSAUpgradeable.toEthSignedMessageHash(messageHash),
            signature
        );
        // GP_NA: Signer Is Not ADmin
        require(signer == _admin, "AKF_NA");
        return (signer, messageHash);
    }

    function createAlphaKeysForV2(
        uint256 twitterId,
        address player,
        string calldata name,
        string calldata symbol
    ) external nonReentrant onlyAdmin {
        require(twitterId > 0, "AKF_TZV");
        require(_playerKeys[player] == address(0), "AKF_PNZA");
        require(_twitterKeys[twitterId] == address(0), "AKF_TNZA");
        //
        IAlphaKeysToken token = IAlphaKeysToken(
            address(new AlphaKeysTokenProxy())
        );
        token.initialize(address(this), player, name, symbol);
        //
        _playerKeys[player] = address(token);
        _keysPlayers[address(token)] = player;
        _twitterKeys[twitterId] = address(token);
        _keysTwitters[address(token)] = twitterId;
        //
        emit AlphaKeysCreatedV2(player, address(token), twitterId);
    }

    function createAlphaKeysForTwitter(
        uint256 twitterId,
        string calldata name,
        string calldata symbol,
        bytes memory signature
    ) external notContract nonReentrant {
        require(_twitterKeys[twitterId] == address(0), "AKF_TNZA");
        _verifyCreateTokenSigner(twitterId, name, symbol, signature);
        //
        IAlphaKeysToken token = IAlphaKeysToken(
            address(new AlphaKeysTokenProxy())
        );
        token.initialize(address(this), address(0), name, symbol);
        _twitterKeys[twitterId] = address(token);
        _keysTwitters[address(token)] = twitterId;
        //
        emit AlphaKeysCreatedForTwitter(address(0), address(token), twitterId);
    }

    function updateKeysPlayer(
        address token,
        address newPlayer
    ) external nonReentrant onlyAdmin {
        require(_playerKeys[newPlayer] == address(0), "AKF_PNZA");
        address oldPlayer = _keysPlayers[token];
        _playerKeys[oldPlayer] = address(0);
        //
        IAlphaKeysToken tokenIns = IAlphaKeysToken(token);
        tokenIns.updateNewPlayer(newPlayer);
        //
        _keysPlayers[token] = newPlayer;
        _playerKeys[newPlayer] = token;
    }

    function updateTwitterId(
        uint256 twitterId,
        address token
    ) external onlyAdmin onlyToken(token) {
        if (
            _twitterKeys[twitterId] == address(0) && _keysTwitters[token] == 0
        ) {
            _twitterKeys[twitterId] = token;
            _keysTwitters[token] = twitterId;
        }
    }

    // for migrate BTC

    function refundTC(uint256 amount) external nonReentrant onlyOwner {
        TransferHelper.safeTransferETH(owner(), amount);
    }

    function refundBTC(uint256 amount) external nonReentrant onlyOwner {
        address btc = _btc;
        TransferHelper.safeTransfer(btc, owner(), amount);
    }

    function requestFund(
        address token,
        address from,
        uint256 amount
    ) external onlyToken(_msgSender()) {
        if (amount > 0) {
            address vault = _vault;
            if (from == address(this)) {
                TransferHelper.safeTransfer(token, vault, amount);
            } else if (from != vault) {
                TransferHelper.safeTransferFrom(token, from, vault, amount);
            }
        }
    }

    function requestRefund(
        address token,
        address to,
        uint256 amount
    ) external onlyToken(_msgSender()) {
        if (amount > 0) {
            address vault = _vault;
            if (to != vault) {
                TransferHelper.safeTransferFrom(token, vault, to, amount);
            }
        }
    }

    // for buy keys

    function _buyKeysForV2ByToken(
        address token,
        address from,
        uint256 amountX18,
        uint256 buyPriceAfterFeeMax,
        address recipient,
        TokenTypes.OrderType orderType
    ) internal onlyToken(token) returns (uint256) {
        uint256 buyPriceAfterFee = IAlphaKeysToken(token).getBuyPriceAfterFeeV2(
            amountX18
        );
        require(buyPriceAfterFeeMax >= buyPriceAfterFee, "AKF_BBP");
        //
        IAlphaKeysToken(token).permitBuyKeysForV2(
            from,
            amountX18,
            recipient,
            orderType
        );
        return buyPriceAfterFee;
    }

    function _buyKeysForV2ByToken(
        address token,
        address from,
        uint256 amountX18,
        address recipient,
        TokenTypes.OrderType orderType
    ) internal onlyToken(token) {
        IAlphaKeysToken(token).permitBuyKeysForV2(
            from,
            amountX18,
            recipient,
            orderType
        );
    }

    function _sellKeysForV2ByToken(
        address token,
        address from,
        uint256 amountX18,
        uint256 sellPriceAfterFeeMin,
        address recipient,
        TokenTypes.OrderType orderType
    ) internal onlyToken(token) {
        require(
            sellPriceAfterFeeMin <=
                IAlphaKeysToken(token).getSellPriceAfterFeeV2(amountX18),
            "AKF_BSP"
        );
        IAlphaKeysToken(token).permitSellKeysForV2(
            from,
            amountX18,
            recipient,
            orderType
        );
    }

    function _sellKeysForV2ByToken(
        address token,
        address from,
        uint256 amountX18,
        address recipient,
        TokenTypes.OrderType orderType
    ) internal onlyToken(token) {
        IAlphaKeysToken(token).permitSellKeysForV2(
            from,
            amountX18,
            recipient,
            orderType
        );
    }

    function buyKeysForV2ByTwitterId(
        uint256 twitterId,
        uint256 amountX18,
        uint256 buyPriceAfterFeeMax,
        address recipient
    ) external notContract nonReentrant {
        address token = _twitterKeys[twitterId];
        _buyKeysForV2ByToken(
            token,
            _msgSender(),
            amountX18,
            buyPriceAfterFeeMax,
            recipient,
            TokenTypes.OrderType.SpotOrder
        );
    }

    function buyKeysV2ByToken(
        address token,
        uint256 amountX18,
        uint256 buyPriceAfterFeeMax
    ) external notContract nonReentrant {
        _buyKeysForV2ByToken(
            token,
            _msgSender(),
            amountX18,
            buyPriceAfterFeeMax,
            _msgSender(),
            TokenTypes.OrderType.SpotOrder
        );
    }

    function buyKeysForV2ByToken(
        address token,
        uint256 amountX18,
        uint256 buyPriceAfterFeeMax,
        address recipient
    ) external notContract nonReentrant {
        _buyKeysForV2ByToken(
            token,
            _msgSender(),
            amountX18,
            buyPriceAfterFeeMax,
            recipient,
            TokenTypes.OrderType.SpotOrder
        );
    }

    function sellKeysV2ByToken(
        address token,
        uint256 amountX18,
        uint256 sellPriceAfterFeeMin
    ) external notContract nonReentrant {
        _sellKeysForV2ByToken(
            token,
            _msgSender(),
            amountX18,
            sellPriceAfterFeeMin,
            _msgSender(),
            TokenTypes.OrderType.SpotOrder
        );
    }

    function sellKeysForV2ByToken(
        address token,
        uint256 amountX18,
        uint256 sellPriceAfterFeeMin,
        address recipient
    ) external notContract nonReentrant {
        _sellKeysForV2ByToken(
            token,
            _msgSender(),
            amountX18,
            sellPriceAfterFeeMin,
            recipient,
            TokenTypes.OrderType.SpotOrder
        );
    }

    // for gas station

    function getGasOrderMessageHash(
        uint256 nonce,
        address trader,
        uint256 amountBTC,
        uint256 rate,
        uint256 deadline
    ) public view returns (bytes32) {
        uint256 chainId;
        assembly {
            chainId := chainid()
        }
        return
            keccak256(
                abi.encode(
                    address(this),
                    chainId,
                    nonce,
                    trader,
                    amountBTC,
                    rate,
                    deadline
                )
            );
    }

    function _verifyGasOrderTrader(
        uint256 nonce,
        address trader,
        uint256 amountBTC,
        uint256 rate,
        uint256 deadline,
        bytes memory signature
    ) internal view returns (address, bytes32) {
        bytes32 messageHash = getGasOrderMessageHash(
            nonce,
            trader,
            amountBTC,
            rate,
            deadline
        );
        address signer = ECDSAUpgradeable.recover(
            ECDSAUpgradeable.toEthSignedMessageHash(messageHash),
            signature
        );
        // GP_NA: Signer Is Not ADmin
        require(signer == trader, "AKF_NT");
        return (signer, messageHash);
    }

    function requestTC(
        uint256 nonce,
        address trader,
        uint256 amountBTC,
        uint256 rate,
        uint256 deadline,
        bytes memory signature
    ) external notContract nonReentrant {
        require(amountBTC <= (0.00005 ether), "AKF_IA");
        require(!_usedNonces[trader][nonce], "AKF_BN");
        _usedNonces[trader][nonce] = true;
        //
        uint256 btcPrice = _btcPrice;
        require(rate == btcPrice && btcPrice > 0, "AKF_BR");
        //
        require(deadline >= _blockTimestamp(), "AKF_BD");
        //
        _verifyGasOrderTrader(
            nonce,
            trader,
            amountBTC,
            rate,
            deadline,
            signature
        );
        address btc = _btc;
        require(
            IERC20Upgradeable(btc).balanceOf(trader) >= amountBTC,
            "AKF_IBB"
        );
        //
        uint256 amountTC = amountBTC.mulPrice(btcPrice);
        //
        TransferHelper.safeTransferFrom(_btc, trader, address(this), amountBTC);
        TransferHelper.safeTransferETH(trader, amountTC);
        //
        emit TCRequested(trader, nonce, amountBTC, amountTC);
    }

    // for 3 3 order book

    function createThreeThreeOrderId(
        address tokenA,
        address tokenB,
        uint256 amount,
        uint256 buyPriceBAfterFeeMax
    ) public view returns (bytes32) {
        uint256 chainId;
        assembly {
            chainId := chainid()
        }
        return
            keccak256(
                abi.encode(
                    address(this),
                    chainId,
                    tokenA,
                    tokenB,
                    amount,
                    buyPriceBAfterFeeMax,
                    _blockNumber()
                )
            );
    }

    function getOrder(
        bytes32 orderId
    ) public view returns (ThreeThreeTypes.Order memory order) {
        return _threeThreeOrders[orderId];
    }

    // function threeThreeRequest(
    //     address tokenB,
    //     uint256 amount,
    //     uint256 buyPriceBAfterFeeMax
    // )
    //     external
    //     notContract
    //     nonReentrant
    //     onlyPlayer(_msgSender())
    //     onlyToken(tokenB)
    // {
    //     require(amount >= NumberMath.PRICE_UNIT, "AKF_ANV");
    //     //
    //     require(
    //         buyPriceBAfterFeeMax >=
    //             IAlphaKeysToken(tokenB).getBuyPriceAfterFeeV2(amount),
    //         "AKF_BBPM"
    //     );
    //     //
    //     address tokenA = _playerKeys[_msgSender()];
    //     require(tokenA != tokenB, "AKF_NET");
    //     //
    //     address ownerA = IAlphaKeysToken(tokenA).getPlayer();
    //     //
    //     require(_msgSender() == ownerA, "AKF_NOA");
    //     require(
    //         IERC20Upgradeable(_btc).balanceOf(ownerA) >= buyPriceBAfterFeeMax,
    //         "AKF_OANEB"
    //     );
    //     //
    //     bytes32 orderId = createThreeThreeOrderId(
    //         tokenA,
    //         tokenB,
    //         amount,
    //         buyPriceBAfterFeeMax
    //     );
    //     //
    //     require(_threeThreeOrders[orderId].tokenA == address(0), "AKF_BOI");
    //     //
    //     address ownerB = IAlphaKeysToken(tokenB).getPlayer();
    //     //
    //     _threeThreeOrders[orderId] = ThreeThreeTypes.Order({
    //         status: ThreeThreeTypes.OrderStatus.Unfilled,
    //         tokenA: tokenA,
    //         ownerA: ownerA,
    //         tokenB: tokenB,
    //         ownerB: ownerB,
    //         amount: amount,
    //         buyPriceBAfterFeeMax: buyPriceBAfterFeeMax,
    //         locked: true,
    //         amountA: 0,
    //         amountB: 0
    //     });
    //     //
    //     TransferHelper.safeTransferFrom(
    //         _btc,
    //         ownerA,
    //         _vault,
    //         buyPriceBAfterFeeMax
    //     );
    //     //
    //     emit ThreeThreeRequested(
    //         orderId,
    //         tokenA,
    //         ownerA,
    //         tokenB,
    //         ownerB,
    //         amount,
    //         buyPriceBAfterFeeMax
    //     );
    // }

    // function threeThreeTrade(
    //     bytes32 orderId,
    //     uint256 buyPriceAAfterFeeMax
    // ) external notContract nonReentrant {
    //     require(buyPriceAAfterFeeMax > 0, "AKF_BPNZ");
    //     //
    //     ThreeThreeTypes.Order storage order = _threeThreeOrders[orderId];
    //     //
    //     require(
    //         order.status == ThreeThreeTypes.OrderStatus.Unfilled,
    //         "AKF_BOS"
    //     );
    //     require(!order.locked, "AKF_BOT");
    //     //
    //     address tokenB = order.tokenB;
    //     address ownerB = IAlphaKeysToken(tokenB).getPlayer();
    //     //
    //     require(_msgSender() == ownerB, "AKF_NOB");
    //     // save ownerB
    //     order.ownerB = ownerB;
    //     order.status = ThreeThreeTypes.OrderStatus.Filled;
    //     //
    //     address ownerA = order.ownerA;
    //     address tokenA = order.tokenA;
    //     uint256 amount = order.amount;
    //     uint256 buyPriceBAfterFeeMax = order.buyPriceBAfterFeeMax;
    //     //
    //     address vault = _vault;
    //     //
    //     uint256 buyPriceAfterFee = _buyKeysForV2ByToken(
    //         tokenB,
    //         vault,
    //         amount,
    //         buyPriceBAfterFeeMax,
    //         ownerA,
    //         TokenTypes.OrderType.ThreeThreeOrder
    //     );
    //     uint256 refundAmount = buyPriceBAfterFeeMax.sub(buyPriceAfterFee);
    //     if (refundAmount > 0) {
    //         TransferHelper.safeTransferFrom(_btc, vault, ownerA, refundAmount);
    //     }
    //     //
    //     _buyKeysForV2ByToken(
    //         tokenA,
    //         ownerB,
    //         amount,
    //         buyPriceAAfterFeeMax,
    //         ownerB,
    //         TokenTypes.OrderType.ThreeThreeOrder
    //     );
    //     //
    //     emit ThreeThreeTrade(orderId, tokenA, ownerA, tokenB, ownerB, amount);
    //     //
    //     IAlphaKeysToken(tokenA).permitLock30D(ownerB, amount);
    //     IAlphaKeysToken(tokenB).permitLock30D(ownerA, amount);
    // }

    function threeThreeRequestBTC(
        address tokenB,
        uint256 buyPriceBAfterFeeMax
    )
        external
        notContract
        nonReentrant
        onlyPlayer(_msgSender())
        onlyToken(tokenB)
    {
        require(buyPriceBAfterFeeMax > 0, "AKF_BPNZ");
        //
        address tokenA = _playerKeys[_msgSender()];
        require(tokenA != tokenB, "AKF_NET");
        //
        require(
            buyPriceBAfterFeeMax >=
                IAlphaKeysToken(tokenA).getBuyPriceAfterFeeV2(
                    NumberMath.PRICE_UNIT
                ) &&
                buyPriceBAfterFeeMax >=
                IAlphaKeysToken(tokenB).getBuyPriceAfterFeeV2(
                    NumberMath.PRICE_UNIT
                ),
            "AKF_BBPM"
        );
        //
        address ownerA = IAlphaKeysToken(tokenA).getPlayer();
        //
        require(_msgSender() == ownerA, "AKF_NOA");
        require(
            IERC20Upgradeable(_btc).balanceOf(ownerA) >= buyPriceBAfterFeeMax,
            "AKF_OANEB"
        );
        //
        bytes32 orderId = createThreeThreeOrderId(
            tokenA,
            tokenB,
            0,
            buyPriceBAfterFeeMax
        );
        //
        require(_threeThreeOrders[orderId].tokenA == address(0), "AKF_BOI");
        //
        address ownerB = IAlphaKeysToken(tokenB).getPlayer();
        //
        _threeThreeOrders[orderId] = ThreeThreeTypes.Order({
            status: ThreeThreeTypes.OrderStatus.Unfilled,
            tokenA: tokenA,
            ownerA: ownerA,
            tokenB: tokenB,
            ownerB: ownerB,
            amount: 0,
            buyPriceBAfterFeeMax: buyPriceBAfterFeeMax,
            locked: true,
            amountA: 0,
            amountB: 0
        });
        //
        TransferHelper.safeTransferFrom(
            _btc,
            ownerA,
            _vault,
            buyPriceBAfterFeeMax
        );
        //
        emit ThreeThreeRequested(
            orderId,
            tokenA,
            ownerA,
            tokenB,
            ownerB,
            0,
            buyPriceBAfterFeeMax
        );
    }

    function threeThreeTradeBTC(
        bytes32 orderId
    ) external notContract nonReentrant {
        ThreeThreeTypes.Order storage order = _threeThreeOrders[orderId];
        //
        require(
            order.status == ThreeThreeTypes.OrderStatus.Unfilled,
            "AKF_BOS"
        );
        require(order.locked, "AKF_ONL");
        require(order.amount == 0, "AKF_ONR");
        //
        address tokenB = order.tokenB;
        address ownerB = IAlphaKeysToken(tokenB).getPlayer();
        //
        require(_msgSender() == ownerB, "AKF_NOB");
        // save ownerB
        order.ownerB = ownerB;
        order.status = ThreeThreeTypes.OrderStatus.Filled;
        //
        address ownerA = order.ownerA;
        address tokenA = order.tokenA;
        uint256 buyPriceBAfterFeeMax = order.buyPriceBAfterFeeMax;
        uint24 protocolFeeRatioA = IAlphaKeysToken(tokenA)
            .getProtocolFeeRatio();
        uint24 playerFeeRatioA = IAlphaKeysToken(tokenA).getPlayerFeeRatio();
        uint256 amountA = NumberMath.getBuyAmountMaxWithCash(
            protocolFeeRatioA,
            playerFeeRatioA,
            tokenA,
            buyPriceBAfterFeeMax
        );
        uint24 protocolFeeRatioB = IAlphaKeysToken(tokenB)
            .getProtocolFeeRatio();
        uint24 playerFeeRatioB = IAlphaKeysToken(tokenB).getPlayerFeeRatio();
        uint256 amountB = NumberMath.getBuyAmountMaxWithCash(
            protocolFeeRatioB,
            playerFeeRatioB,
            tokenB,
            buyPriceBAfterFeeMax
        );
        order.amountA = amountA;
        order.amountB = amountB;
        // AKF_BANM: buy amount not min
        require(amountA > 0 && amountB > 0, "AKF_BANM");
        //
        address vault = _vault;
        //
        uint256 buyPriceAfterFee = _buyKeysForV2ByToken(
            tokenB,
            vault,
            amountB,
            buyPriceBAfterFeeMax,
            ownerA,
            TokenTypes.OrderType.ThreeThreeOrder
        );
        uint256 refundAmount = buyPriceBAfterFeeMax.sub(buyPriceAfterFee);
        if (refundAmount > 0) {
            TransferHelper.safeTransferFrom(_btc, vault, ownerA, refundAmount);
        }
        //
        _buyKeysForV2ByToken(
            tokenA,
            ownerB,
            amountA,
            buyPriceBAfterFeeMax,
            ownerB,
            TokenTypes.OrderType.ThreeThreeOrder
        );
        //
        emit ThreeThreeTradeBTC(
            orderId,
            tokenA,
            ownerA,
            tokenB,
            ownerB,
            amountA,
            amountB
        );
        //
        IAlphaKeysToken(tokenA).permitLock30D(ownerB, amountA);
        IAlphaKeysToken(tokenB).permitLock30D(ownerA, amountB);
    }

    function threeThreeCancel(
        bytes32 orderId
    ) external notContract nonReentrant {
        ThreeThreeTypes.Order storage order = _threeThreeOrders[orderId];
        //
        require(
            order.status == ThreeThreeTypes.OrderStatus.Unfilled,
            "AKF_BOS"
        );
        require(order.locked, "AKF_ONL");
        //
        address tokenA = order.tokenA;
        require(tokenA != address(0), "AKF_ITA");
        //
        address ownerA = IAlphaKeysToken(tokenA).getPlayer();
        require(_msgSender() == ownerA, "AKF_IOA");
        //
        order.status = ThreeThreeTypes.OrderStatus.Cancelled;
        //
        TransferHelper.safeTransferFrom(
            _btc,
            _vault,
            ownerA,
            order.buyPriceBAfterFeeMax
        );
        //
        emit ThreeThreeCancelled(orderId, tokenA, ownerA);
    }

    function threeThreeReject(
        bytes32 orderId
    ) external notContract nonReentrant {
        ThreeThreeTypes.Order storage order = _threeThreeOrders[orderId];
        //
        require(
            order.status == ThreeThreeTypes.OrderStatus.Unfilled,
            "AKF_BOS"
        );
        require(order.locked, "AKF_ONL");
        //
        address tokenB = order.tokenB;
        require(tokenB != address(0), "AKF_ITB");
        //
        address ownerB = IAlphaKeysToken(tokenB).getPlayer();
        require(_msgSender() == ownerB, "AKF_IOB");
        //
        address tokenA = order.tokenA;
        require(tokenA != address(0), "AKF_ITA");
        address ownerA = IAlphaKeysToken(tokenA).getPlayer();
        //
        order.status = ThreeThreeTypes.OrderStatus.Rejected;
        //
        TransferHelper.safeTransferFrom(
            _btc,
            _vault,
            ownerA,
            order.buyPriceBAfterFeeMax
        );
        //
        emit ThreeThreeRejected(orderId, tokenB, ownerB);
    }

    // for limit order

    function limitOrderCreate(
        uint256 nonce,
        address token,
        bool isBuy,
        uint256 amount,
        uint256 triggerPrice,
        uint256 buyPriceAfterFeeMax
    ) external notContract nonReentrant {
        address trader = _msgSender();
        LimitOrderTypes.Order storage order = _limitOrders[trader][nonce];
        require(order.trader == address(0), "AKF_BT");
        require(amount > 0 && buyPriceAfterFeeMax > 0, "AKF_BR");
        //
        order.trader = trader;
        order.token = token;
        order.isBuy = isBuy;
        order.amount = amount;
        order.triggerPrice = triggerPrice;
        order.buyPriceAfterFeeMax = buyPriceAfterFeeMax;
        order.status = LimitOrderTypes.OrderStatus.Unfilled;
        //
        TransferHelper.safeTransferFrom(
            _btc,
            trader,
            _vault,
            buyPriceAfterFeeMax
        );
        //
        emit LimitOrderCreated(
            nonce,
            trader,
            token,
            isBuy,
            amount,
            triggerPrice,
            buyPriceAfterFeeMax
        );
    }

    function limitOrderFill(
        uint256 nonce,
        address trader
    ) external notContract nonReentrant {
        LimitOrderTypes.Order storage order = _limitOrders[trader][nonce];
        require(order.trader == trader, "AKF_BT");
        require(
            order.status == LimitOrderTypes.OrderStatus.Unfilled,
            "AKF_BOS"
        );
        //
        _limitOrders[trader][nonce].status = LimitOrderTypes.OrderStatus.Filled;
        // fill order
        address token = order.token;
        uint256 triggerPrice = order.triggerPrice;
        uint256 amount = order.amount;
        bool isBuy = order.isBuy;
        uint256 buyPriceAfterFeeMax = order.buyPriceAfterFeeMax;
        //
        if (isBuy) {
            require(
                IAlphaKeysToken(token).getBuyPriceV2(NumberMath.ONE_ETHER) <=
                    triggerPrice,
                "AKF_BTBP"
            );
            // fill order
            address vault = _vault;
            uint256 buyPriceAfterFee = _buyKeysForV2ByToken(
                token,
                vault,
                amount,
                buyPriceAfterFeeMax,
                trader,
                TokenTypes.OrderType.LimitOrder
            );
            // refund
            uint256 refundAmount = buyPriceAfterFeeMax.sub(buyPriceAfterFee);
            if (refundAmount > 0) {
                address btc = _btc;
                TransferHelper.safeTransferFrom(
                    btc,
                    vault,
                    trader,
                    refundAmount
                );
            }
        } else {
            require(
                IAlphaKeysToken(token).getBuyPriceV2(NumberMath.ONE_ETHER) >=
                    triggerPrice,
                "AKF_BTSP"
            );
            _sellKeysForV2ByToken(
                token,
                trader,
                amount,
                trader,
                TokenTypes.OrderType.LimitOrder
            );
        }
        emit LimitOrderFilled(nonce, trader, token, isBuy, amount);
    }

    function limitOrderCancel(uint256 nonce) external notContract nonReentrant {
        address trader = _msgSender();
        LimitOrderTypes.Order storage order = _limitOrders[trader][nonce];
        require(order.trader == trader, "AKF_BT");
        require(
            order.status == LimitOrderTypes.OrderStatus.Unfilled,
            "AKF_BOS"
        );
        order.status = LimitOrderTypes.OrderStatus.Cancelled;
        //
        TransferHelper.safeTransferFrom(
            _btc,
            _vault,
            trader,
            order.buyPriceAfterFeeMax
        );
        //
        emit LimitOrderCancelled(nonce, trader);
    }
}
        

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

import {IAlphaKeysFactoryImpl} from "./IAlphaKeysFactoryImpl.sol";

interface IAlphaKeysFactory is IAlphaKeysFactoryImpl {
    //
    event AlphaKeysCreated(address indexed player, address indexed token);
    event AlphaKeysCreatedV2(
        address indexed player,
        address indexed token,
        uint256 indexed twitterId
    );
    event AlphaKeysCreatedForTwitter(
        address indexed player,
        address indexed token,
        uint256 indexed twitterId
    );

    event TCRequested(
        address indexed trader,
        uint256 indexed nonce,
        uint256 amountBTC,
        uint256 amountTC
    );

    event ThreeThreeRequested(
        bytes32 indexed orderId,
        address indexed tokenA,
        address ownerA,
        address indexed tokenB,
        address ownerB,
        uint256 amount,
        uint256 buyPriceBAfterFeeMax
    );

    event ThreeThreeTrade(
        bytes32 indexed orderId,
        address indexed tokenA,
        address ownerA,
        address indexed tokenB,
        address ownerB,
        uint256 amount
    );

    event ThreeThreeTradeBTC(
        bytes32 indexed orderId,
        address indexed tokenA,
        address ownerA,
        address indexed tokenB,
        address ownerB,
        uint256 amountA,
        uint256 amountB
    );

    event ThreeThreeCancelled(
        bytes32 indexed orderId,
        address indexed tokenA,
        address ownerA
    );

    event ThreeThreeRejected(
        bytes32 indexed orderId,
        address indexed tokenB,
        address ownerB
    );

    event LimitOrderCreated(
        uint256 indexed nonce,
        address indexed trader,
        address indexed token,
        bool isBuy,
        uint256 amount,
        uint256 triggerPrice,
        uint256 buyPriceAfterFeeMax
    );

    event LimitOrderFilled(
        uint256 indexed nonce,
        address indexed trader,
        address indexed token,
        bool isBuy,
        uint256 amount
    );

    event LimitOrderCancelled(uint256 indexed nonce, address indexed trader);

    //
    function getBTC() external view returns (address);

    function getVault() external view returns (address);

    function getProtocolFeeRatio() external view returns (uint24);

    function getPlayerFeeRatio() external view returns (uint24);

    function getProtocolFeeDestination() external view returns (address);

    function requestFund(address token, address from, uint256 amount) external;

    function requestRefund(address token, address to, uint256 amount) external;
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

interface IAlphaKeysFactoryImpl {
    function getAlphaKeysTokenImplementation()
        external
        view
        returns (address);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/MathUpgradeable.sol";
import "./math/SignedMathUpgradeable.sol";

/**
 * @dev String operations.
 */
library StringsUpgradeable {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = MathUpgradeable.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMathUpgradeable.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, MathUpgradeable.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../StringsUpgradeable.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSAUpgradeable {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", StringsUpgradeable.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library MathUpgradeable {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

import {TokenTypes} from "../libraries/TokenTypes.sol";

interface IAlphaKeysToken {
    //
    event Trade(
        address trader,
        address player,
        bool isBuy,
        uint256 shareAmount,
        uint256 tcAmount,
        uint256 protocolFeeAmount,
        uint256 playerFeeAmount,
        uint256 supply
    );

    event TradeV2(
        address trader,
        address player,
        bool isBuy,
        uint256 shareAmount,
        uint256 tcAmount,
        uint256 protocolFeeAmount,
        uint256 playerFeeAmount,
        uint256 supply
    );

    event TradeV3(
        address trader,
        address player,
        bool isBuy,
        uint256 shareAmount,
        uint256 btcAmount,
        uint256 protocolBtcFeeAmount,
        uint256 playerBtcFeeAmount,
        uint256 supply
    );

    event TradeV4(
        address trader,
        address player,
        bool isBuy,
        uint256 shareAmount,
        uint256 btcAmount,
        uint256 protocolBtcFeeAmount,
        uint256 playerBtcFeeAmount,
        uint256 supply,
        TokenTypes.OrderType orderType,
        bytes32 orderId
    );

    event PlayerUpdated(address indexed oldPlayer, address indexed newPlayer);

    event BTCMigrated(uint256 amountTC, uint256 amountBTC);

    event LockedTs(
        address user,
        uint256 amount,
        uint256 duationTs,
        uint256 expiredTs
    );

    event PlayerFeeRatioUpdated(uint24 playerFeeRatio);

    //
    function initialize(
        address factory,
        address manager,
        string calldata name,
        string calldata symbol
    ) external;

    function getPlayer() external view returns (address);

    function getProtocolFeeRatio() external view returns (uint24);

    function getPlayerFeeRatio() external view returns (uint24);

    function getBuyPriceAfterFeeV2(
        uint256 amountX18
    ) external view returns (uint256);

    function getBuyPriceV2(uint256 amountX18) external view returns (uint256);

    function getSellPriceAfterFeeV2(
        uint256 amountX18
    ) external view returns (uint256);

    function updateNewPlayer(address newPlayer) external;

    function permitBuyKeysForV2(
        address from,
        uint256 amountX18,
        address recipient,
        TokenTypes.OrderType orderType
    ) external;

    function permitSellKeysForV2(
        address from,
        uint256 amountX18,
        address recipient,
        TokenTypes.OrderType orderType
    ) external;

    function permitLock30D(address user, uint256 amount) external;
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

import {TokenTypes} from "../libraries/TokenTypes.sol";

interface IAlphaKeysVault {
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/SafeMath.sol)

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMathUpgradeable {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMathUpgradeable {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (proxy/Proxy.sol)

pragma solidity ^0.8.0;

/**
 * @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
 * instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
 * be specified by overriding the virtual {_implementation} function.
 *
 * Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
 * different contract through the {_delegate} function.
 *
 * The success and return data of the delegated call will be returned back to the caller of the proxy.
 */
abstract contract Proxy {
    /**
     * @dev Delegates the current call to `implementation`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _delegate(address implementation) internal virtual {
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())

            // Call the implementation.
            // out and outsize are 0 because we don't know the size yet.
            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)

            // Copy the returned data.
            returndatacopy(0, 0, returndatasize())

            switch result
            // delegatecall returns 0 on error.
            case 0 {
                revert(0, returndatasize())
            }
            default {
                return(0, returndatasize())
            }
        }
    }

    /**
     * @dev This is a virtual function that should be overridden so it returns the address to which the fallback function
     * and {_fallback} should delegate.
     */
    function _implementation() internal view virtual returns (address);

    /**
     * @dev Delegates the current call to the address returned by `_implementation()`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _fallback() internal virtual {
        _beforeFallback();
        _delegate(_implementation());
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
     * function in the contract matches the call data.
     */
    fallback() external payable virtual {
        _fallback();
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if call data
     * is empty.
     */
    receive() external payable virtual {
        _fallback();
    }

    /**
     * @dev Hook that is called before falling back to the implementation. Can happen as part of a manual `_fallback`
     * call, or as part of the Solidity `fallback` or `receive` functions.
     *
     * If overridden should call `super._beforeFallback()`.
     */
    function _beforeFallback() internal virtual {}
}
          

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.0;

import {Proxy} from "@openzeppelin/contracts/proxy/Proxy.sol";
import {IAlphaKeysFactoryImpl} from "./interfaces/IAlphaKeysFactoryImpl.sol";

/**
 * @title AlphaKeysTokenProxy
 * @author 0xkongamoto
 */
contract AlphaKeysTokenProxy is Proxy {
    //
    IAlphaKeysFactoryImpl public immutable factory;

    // ======== Constructor =========
    constructor() {
        factory = IAlphaKeysFactoryImpl(msg.sender);
    }

    /**
     * @dev This is a virtual function that should be overridden so it returns the address to which the fallback function
     * and {_fallback} should delegate.
     */
    function _implementation()
        internal
        view
        virtual
        override
        returns (address impl)
    {
        return factory.getAlphaKeysTokenImplementation();
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

abstract contract BlockContext {
    function _blockTimestamp() internal view virtual returns (uint256) {
        // Reply from Arbitrum
        // block.timestamp returns timestamp at the time at which the sequencer receives the tx.
        // It may not actually correspond to a particular L1 block
        return block.timestamp;
    }

    function _blockNumber() internal view virtual returns (uint256) {
        return block.number;
    }
}
          

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >0.8.0;

/// @title Multicall
/// @notice Enables calling multiple methods in a single call to the contract
abstract contract Multicall {
    function multicall(
        bytes[] calldata data
    ) public payable returns (bytes[] memory results) {
        results = new bytes[](data.length);
        for (uint256 i = 0; i < data.length; i++) {
            (bool success, bytes memory result) = address(this).delegatecall(
                data[i]
            );

            if (!success) {
                // Next 5 lines from https://ethereum.stackexchange.com/a/83577
                if (result.length < 68) revert();
                assembly {
                    result := add(result, 0x04)
                }
                revert(abi.decode(result, (string)));
            }

            results[i] = result;
        }
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.0;

library LimitOrderTypes {
    enum OrderStatus {
        Unfilled,
        Filled,
        CancelledNotRefund,
        Cancelled
    }

    struct Order {
        OrderStatus status;
        address trader;
        address token;
        bool isBuy;
        uint256 amount;
        uint256 triggerPrice;
        uint256 buyPriceAfterFeeMax;
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.0;

import {SafeMathUpgradeable} from "@openzeppelin/contracts-upgradeable/utils/math/SafeMathUpgradeable.sol";
import {IERC20Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";

library NumberMath {
    // CONST
    uint256 internal constant RATIO = 1e6;
    using SafeMathUpgradeable for uint256;

    uint256 internal constant ONE_ETHER = 1 ether;
    uint256 internal constant PRICE_UNIT = 0.1 ether;
    uint256 internal constant NUMBER_UNIT_PER_ONE_ETHER =
        ONE_ETHER / PRICE_UNIT;

    uint256 internal constant PRICE_BTC_PER_TC = 0.000416666666666667 ether; // 1 BTC = 2400 TC
    uint256 internal constant PRICE_TC_PER_BTC = 2400 ether; // 1 BTC = 2400 TC
    uint256 internal constant PRICE_KEYS_DENOMINATOR = 264000;

    uint256 internal constant TS_30_DAYS = 30 days;

    //
    function mulRatio(
        uint256 value,
        uint24 ratio
    ) internal pure returns (uint256) {
        return value.mul(ratio).div(RATIO);
    }

    function mulEther(uint256 value) internal pure returns (uint256) {
        return value.mul(1 ether);
    }

    function divEther(uint256 value) internal pure returns (uint256) {
        return value.div(1 ether);
    }

    function mulPrice(
        uint256 value,
        uint256 rate
    ) internal pure returns (uint256) {
        return value.mul(rate).div(1 ether);
    }

    function getPriceV2(
        uint256 supply,
        uint256 amount
    ) internal pure returns (uint256) {
        uint256 sum1 = supply == 0
            ? 0
            : ((supply - NUMBER_UNIT_PER_ONE_ETHER) *
                supply *
                (2 *
                    (supply - NUMBER_UNIT_PER_ONE_ETHER) +
                    NUMBER_UNIT_PER_ONE_ETHER)) / 6;
        uint256 sum2 = supply == 0 && amount == 1
            ? 0
            : ((supply - NUMBER_UNIT_PER_ONE_ETHER + amount) *
                (supply + amount) *
                (2 *
                    (supply - NUMBER_UNIT_PER_ONE_ETHER + amount) +
                    NUMBER_UNIT_PER_ONE_ETHER)) / 6;
        uint256 summation = sum2 - sum1;
        return
            (summation * ONE_ETHER) /
            PRICE_KEYS_DENOMINATOR /
            (NUMBER_UNIT_PER_ONE_ETHER *
                NUMBER_UNIT_PER_ONE_ETHER *
                NUMBER_UNIT_PER_ONE_ETHER);
    }

    function getBuyPriceV2(
        uint256 supply,
        uint256 amountX18
    ) internal pure returns (uint256) {
        return
            getPriceV2(supply.div(PRICE_UNIT), amountX18.div(PRICE_UNIT)).add(
                1
            );
    }

    function getBuyPriceV2AfterFee(
        uint24 protocolFeeRatio,
        uint24 playerFeeRatio,
        uint256 supply,
        uint256 amountX18
    ) internal pure returns (uint256) {
        //
        uint256 price = getBuyPriceV2(supply, amountX18);
        uint256 protocolFee = mulRatio(price, protocolFeeRatio);
        uint256 playerFee = mulRatio(price, playerFeeRatio);
        return price.add(protocolFee).add(playerFee);
    }

    function getBuyAmountMaxWithCash(
        uint24 protocolFeeRatio,
        uint24 playerFeeRatio,
        address token,
        uint256 buyPriceAfterFeeMax
    ) internal view returns (uint256) {
        uint256 supply = IERC20Upgradeable(token).totalSupply();
        uint256 amount = 0;
        while (true) {
            uint256 buyPriceAfterFee = getBuyPriceV2AfterFee(
                protocolFeeRatio,
                playerFeeRatio,
                supply,
                amount.add(ONE_ETHER)
            );
            if (buyPriceAfterFee > buyPriceAfterFeeMax) {
                while (true) {
                    buyPriceAfterFee = getBuyPriceV2AfterFee(
                        protocolFeeRatio,
                        playerFeeRatio,
                        supply,
                        amount.add(PRICE_UNIT)
                    );
                    if (buyPriceAfterFee > buyPriceAfterFeeMax) {
                        break;
                    }
                    amount = amount.add(PRICE_UNIT);
                }
                break;
            }
            amount = amount.add(ONE_ETHER);
        }
        return amount;
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.0;

library ThreeThreeTypes {
    enum OrderStatus {
        Unfilled,
        Filled,
        Cancelled,
        Rejected
    }

    struct Order {
        OrderStatus status;
        address tokenA;
        address ownerA;
        address tokenB;
        address ownerB;
        uint256 amount;
        uint256 buyPriceBAfterFeeMax;
        bool locked;
        uint256 amountA;
        uint256 amountB;
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.0;

library TokenTypes {
    enum OrderType {
        SpotOrder,
        ThreeThreeOrder,
        LimitOrder,
        WatchlistOrder
    }

    struct Locked {
        uint256 amount;
        uint256 expiredTs;
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later

pragma solidity >=0.8.0;

// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false
library TransferHelper {
    function safeApprove(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('approve(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x095ea7b3, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeApprove: approve failed'
        );
    }

    function safeTransfer(
        address token,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transfer(address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0xa9059cbb, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::safeTransfer: transfer failed'
        );
    }

    function safeTransferFrom(
        address token,
        address from,
        address to,
        uint256 value
    ) internal {
        // bytes4(keccak256(bytes('transferFrom(address,address,uint256)')));
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x23b872dd, from, to, value));
        require(
            success && (data.length == 0 || abi.decode(data, (bool))),
            'TransferHelper::transferFrom: transferFrom failed'
        );
    }

    function safeTransferETH(address to, uint256 value) internal {
        (bool success, ) = to.call{value: value}(new bytes(0));
        require(success, 'TransferHelper::safeTransferETH: ETH transfer failed');
    }
}
          

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity >=0.8.0;

import {ThreeThreeTypes} from "../libraries/ThreeThreeTypes.sol";
import {LimitOrderTypes} from "../libraries/LimitOrderTypes.sol";

abstract contract AlphaKeysFactoryStorage {
    //
    address internal _playerShareTokenImplementation;
    //
    uint24 internal _protocolFeeRatio;
    uint24 internal _playerFeeRatio;
    address internal _protocolFeeDestination;
    //
    mapping(address => address) internal _playerKeys;
    mapping(address => address) internal _keysPlayers;
    mapping(uint256 => address) internal _twitterKeys;
    mapping(address => uint256) internal _keysTwitters;
    //
    address internal _admin;
    address internal _btc;
    uint256 internal _btcPrice;
    // for gas
    mapping(address => mapping(uint256 => bool)) _usedNonces;
    // three three model
    mapping(bytes32 => ThreeThreeTypes.Order) _threeThreeOrders;
    // vault address
    address internal _vault;
    address internal _swapRouter;
    // limit orders
    mapping(address => mapping(uint256 => LimitOrderTypes.Order)) _limitOrders;
}